∇-Nabla: Numerical Analysis BAsed LAnguage

aligned auto 
break 
char const continue 
do double
else extern
float for
if inline int 
long
register restrict return
short signed sizeof static 
unsigned
void volatile
while

all
Bool backCell 
cell Cell cells coord  
face Face faces forall foreach frontCell
global
in inner inout Integer  
node Node nodes 
options out outer own
particle Particle particles
Real Real3 Real3x3
this
Uid
with

L                 [a-zA-Z_αβγδεζηθικλμνξοπρςστυφχψωΑΒΓΔΕΖΗΘΙΚΛΜΝΞΟΠΡΣΤΥΦΧΨΩ𝜕]

D                 [0-9]                         // Digit
H                 [a-fA-F0-9]                   // Hexadecimal
E                 [Ee][+-]?{D}+                 // Exponent
FS                (f|F|l|L)                     // Floating point suffix
IS                (u|U|l|L)*                    // Integer suffix
ℍ                 0[x]{H}+{IS}?                 // Hexadecimal digit
ℤ                 {D}+{IS}?                     // Integer digit
ℝ                 {D}+{E}{FS}?                  // Real digit
ℝ                 {D}*"."{D}+({E})?{FS}?        // Real digit
ℝ                 {D}+"."{D}*({E})?{FS}?        // Real digit

IDENTIFIER        {L}({L}|{D})*
LC                L?'(\\.|[^\'])+'              // Long-wide character

STRING_LITERAL    L?\"(\\.|[^\\\"])*\"

[ ] ( ) { } . ->
++ -- & * + - ~ !
/ % << >> < > <= >= == != ^ | && ||
? : ; , ...
= *= /= %= += -= <<= >>= &= ^= |=
<?= >?= ?=
# @ ∀ ℵ ∧ ∨ 
∞ ² ³ √ ∛ ½ ⅓ ¼ ⅛
⋅ ⨯ ⤫ ⊗ ⨂ ⊛

[ \t\v\f]                   // ignored terminals

/*                          // ignored comments bloc
//                          // ignored comment line

∇_grammar
: with_library                // Library declaration
| declaration                 // Preprocessing, Includes
| ∇_options_definition        // ∇ options definition
| ∇_item_definition           // Cell, Node, Face & Particle variables definition
| function_definition         // C function definition
| ∇_job_definition            // ∇ job definition
| ∇_reduction                 // ∇ reduction job definition
;

type_specifier
: void 
| char
| short
| int 
| long 
| float
| double 
| signed
| Bool
| ℝ³ | Real3
| Real3x3
| ℝ | Real
| ℕ | unsigned
| ℤ | Integer
| Cell | Face | Node | Particle
| Uid
;

start_scope: '{' ;          // Common starting scope
end_scope
: '}'                       // Standard ending scope
| '}' @ at_constant         // ∇ ending scope with an '@' statement
;

single_library:
| PARTICLES                   // Additionnal 'particle' keyword
| LIB_ALEPH                   // ℵ keywords for implicit schemes
| LIB_SLURM                   // time, limit & remain keywords
| LIB_MATHEMATICA             // Mathematica keywords
;
with_library_list
: single_library
| with_library_list ',' single_library 
;
with_library: with with_library_list ';';

∇_options_definition
: options '{' ∇_option_declaration_list '}' ';' 
;
∇_option_declaration_list
: ∇_option_declaration 
| ∇_option_declaration_list ∇_option_declaration
;
∇_option_declaration
: type_specifier direct_declarator ';' 
| type_specifier direct_declarator '=' expression ';'   
| preproc 
;

∇_item
: cell
| node
| face
| particle
;

∇_items
: cells
| nodes
| faces
| global
| particles
;

∇_scope: own | all;

∇_region: inner | outer;

∇_family
: ∇_items 
| ∇_scope ∇_items 
| ∇_region ∇_items 
| ∇_scope ∇_region ∇_items 
;

∇_system
: uid | this | iteration
| nbNode | nbCell 
| backCell | frontCell 
| nextCell | prevCell 
| nextNode | prevNode 
| time remain limit
| exit | mail 
;

∇_item_definition
: ∇_items '{' ∇_item_declaration_list '}' ';' 
;    
∇_item_declaration_list
: ∇_item_declaration 
| ∇_item_declaration_list ∇_item_declaration 
;
∇_item_declaration
: type_name ∇_direct_declarator ';' 
| preproc 
;
∇_direct_declarator
: IDENTIFIER 
| IDENTIFIER '[' ∇_items ']'
| IDENTIFIER '[' primary_expression ']';

∇_parameter_list
: ∇_parameter 
| ∇_parameter_declaration
| ∇_parameter_list ∇_parameter
| ∇_parameter_list ',' ∇_parameter_declaration
;
∇_parameter
: ∇_in_parameter_list
| ∇_out_parameter_list 
| ∇_inout_parameter_list 
;
∇_in_parameter_list: in '(' ∇_parameter_list ')';
∇_out_parameter_list: out '(' ∇_parameter_list ')';
∇_inout_parameter_list: inout '(' ∇_parameter_list ')' ;

∇_prefix: ∇_family | ∀ ∇_family ;
∇_job_definition
: ∇_prefix decl_specifiers IDENTIFIER '(' param_type_list ')' compound_statement 
| ∇_prefix decl_specifiers IDENTIFIER '(' param_type_list ')' ∇_param_list compound_statement 
| ∇_prefix decl_specifiers IDENTIFIER '(' param_type_list ')' @ at_constant compound_statement 
| ∇_prefix decl_specifiers IDENTIFIER '(' param_type_list ')' @ at_constant if '(' constant_expression ')' compound_statement 
| ∇_prefix decl_specifiers IDENTIFIER '(' param_type_list ')' ∇_param_list @ at_constant compound_statement 
| ∇_prefix decl_specifiers IDENTIFIER '(' param_type_list ')' ∇_param_list @ at_constant if '(' constant_expression ')' compound_statement
;

function_definition
: declaration_specifiers declarator declaration_list compound_statement 
| declaration_specifiers declarator declaration_list @ at_constant compound_statement 
| declaration_specifiers declarator compound_statement 
| declaration_specifiers declarator @ at_constant compound_statement 
;

primary_expression
: # 
| ∞ 
| ∇_item
| ∇_system 
| ℍ  | ℤ | ℝ 
| ½ | ⅓ | ¼ | ⅛ 
| IDENTIFIER 
| QUOTE_LITERAL 
| STRING_LITERAL 
| '(' expression ')' 
;

postfix_expression
: primary_expression
| postfix_expression FORALL_NODE_INDEX 
| postfix_expression FORALL_CELL_INDEX
| postfix_expression FORALL_MTRL_INDEX 
| postfix_expression '[' expression ']'
| REAL '(' ')'
| REAL '(' expression ')'
| REAL3 '(' ')'
| REAL3 '(' expression ')' 
| REAL3x3 '(' ')'
| REAL3x3 '(' expression ')'
| postfix_expression '(' ')'
| FATAL '(' argument_expression_list ')'
| postfix_expression '(' argument_expression_list ')'
| postfix_expression '.' IDENTIFIER 
| postfix_expression '.' ∇_item '(' ℤ ')'
| postfix_expression '.' ∇_system 
| postfix_expression PTR_OP primary_expression 
| postfix_expression INC_OP 
| postfix_expression DEC_OP 
| postfix_expression SUPERSCRIPT_DIGIT_TWO
| postfix_expression SUPERSCRIPT_DIGIT_THREE 
| aleph_expression
;

unary_expression
: postfix_expression
| '√'  unary_expression
| '∛'  unary_expression
| '++' unary_expression
| '--' unary_expression
| '&'  unary_expression
| unary_prefix_operator cast_expression
| SIZEOF unary_expression
| SIZEOF '(' type_name ')';

multiplicative_expression
: cast_expression
| multiplicative_expression '*' cast_expression
| multiplicative_expression '/' cast_expression 
| multiplicative_expression '%' cast_expression
| multiplicative_expression '⨯' cast_expression // for vectors cross product. 
| multiplicative_expression '⋅' cast_expression // for vectors dot products.
| multiplicative_expression '⊗' cast_expression
| multiplicative_expression '⊛' cast_expression; // for the products matrices, and tensors.

assignment_expression
: conditional_expression
| unary_expression assignment_operator assignment_expression
| unary_expression assignment_operator logical_or_expression '?' expression
;

aleph_vector: rhs | lhs ;
aleph_expression
: aleph_vector
| ℵ aleph_vector reset 
| ℵ solve 
| ℵ aleph_vector newValue | addValue | setValue
| ℵ matrix addValue | ℵ matrix setValue 
| ℵ lhs getValue | ℵ rhs getValue 
;

expression_statement
: ';'
| expression ';'
| expression @ at_constant';' 
;

iteration_statement
: ∀ ∇_item statement
| ∀ ∇_item @ at_constant statement
| ∀ ∇_matenv statement
| ∀ ∇_matenv @ at_constant statement
| ∀ IDENTIFIER cell statement
| ∀ IDENTIFIER node statement
| ∀ IDENTIFIER face statement
| ∀ IDENTIFIER particle statement
| while '(' expression ')' statement 
| do statement while '(' expression ')' ';' 
| for '(' expression_statement expression_statement ')' statement 
| for '(' expression_statement expression_statement expression ')' statement 
| for '(' type_specifier expression_statement expression_statement ')' statement 
| for '(' type_specifier expression_statement expression_statement expression ')' statement 
;

∇_reduction
: ∀ ∇_items IDENTIFIER <?= IDENTIFIER  @ at_constant ';'
| ∀ ∇_items IDENTIFIER >?= IDENTIFIER  @ at_constant ';'
;

at_single_constant
: ℤ | ℝ 
| '-' ℤ | '+' ℤ 
| '-' ℝ | '+' ℝ 
;
at_constant
: at_single_constant
| at_constant ',' at_single_constant